PL/SQL – 异常

在本章中，我们将讨论 PL/SQL 中的异常。异常是程序执行期间的错误条件。PL/SQL 支持程序员在程序中使用EXCEPTION块来捕捉这种情况，并对错误情况采取适当的行动。有两种类型的例外 –

• 系统定义的异常
• 用户定义的异常

异常处理的语法

异常处理的一般语法如下。在这里，您可以列出尽可能多的例外情况。默认异常将使用WHEN 其他 THEN处理–

DECLARE 
   <declarations section> 
BEGIN 
   <executable command(s)> 
EXCEPTION 
   <exception handling goes here > 
   WHEN exception1 THEN  
      exception1-handling-statements  
   WHEN exception2  THEN  
      exception2-handling-statements  
   WHEN exception3 THEN  
      exception3-handling-statements 
   ........ 
   WHEN others THEN 
      exception3-handling-statements 
END;

例子

让我们写一段代码来说明这个概念。我们将使用我们在前几章中创建和使用的 CUSTOMERS 表 –

DECLARE 
   c_id customers.id%type := 8; 
   c_name customerS.Name%type; 
   c_addr customers.address%type; 
BEGIN 
   SELECT  name, address INTO  c_name, c_addr 
   FROM customers 
   WHERE id = c_id;  
   DBMS_OUTPUT.PUT_LINE ('Name: '||  c_name); 
   DBMS_OUTPUT.PUT_LINE ('Address: ' || c_addr); 

EXCEPTION 
   WHEN no_data_found THEN 
      dbms_output.put_line('No such customer!'); 
   WHEN others THEN 
      dbms_output.put_line('Error!'); 
END; 
/

在 SQL 提示符下执行上述代码时，会产生以下结果 –

No such customer!  

PL/SQL procedure successfully completed. 

上述程序显示给定 ID 的客户的姓名和地址。由于我们的数据库中没有 ID 值为 8 的客户，程序会引发运行时异常NO_DATA_FOUND，该异常在EXCEPTION 块中捕获。

引发异常

每当出现任何内部数据库错误时，数据库服务器都会自动引发异常，但程序员可以使用命令RAISE显式引发异常。以下是引发异常的简单语法 –

DECLARE 
   exception_name EXCEPTION; 
BEGIN 
   IF condition THEN 
      RAISE exception_name; 
   END IF; 
EXCEPTION 
   WHEN exception_name THEN 
   statement; 
END; 

您可以使用上述语法来引发 Oracle 标准异常或任何用户定义的异常。在下一节中，我们将为您提供一个引发用户定义异常的示例。您可以以类似的方式引发 Oracle 标准异常。

用户定义的异常

PL/SQL 允许您根据程序的需要定义自己的异常。必须使用 RAISE 语句或过程DBMS_STANDARD.RAISE_APPLICATION_ERROR声明并显式引发用户定义的异常。

声明异常的语法是 –

DECLARE 
   my-exception EXCEPTION; 

例子

下面的例子说明了这个概念。该程序要求输入客户 ID，当用户输入无效 ID 时，会引发异常invalid_id。

DECLARE 
   c_id customers.id%type := &cc_id; 
   c_name customerS.Name%type; 
   c_addr customers.address%type;  
   -- user defined exception 
   ex_invalid_id  EXCEPTION; 
BEGIN 
   IF c_id <= 0 THEN 
      RAISE ex_invalid_id; 
   ELSE 
      SELECT  name, address INTO  c_name, c_addr 
      FROM customers 
      WHERE id = c_id;
      DBMS_OUTPUT.PUT_LINE ('Name: '||  c_name);  
      DBMS_OUTPUT.PUT_LINE ('Address: ' || c_addr); 
   END IF; 

EXCEPTION 
   WHEN ex_invalid_id THEN 
      dbms_output.put_line('ID must be greater than zero!'); 
   WHEN no_data_found THEN 
      dbms_output.put_line('No such customer!'); 
   WHEN others THEN 
      dbms_output.put_line('Error!');  
END; 
/

在 SQL 提示符下执行上述代码时，会产生以下结果 –

Enter value for cc_id: -6 (let's enter a value -6) 
old  2: c_id customers.id%type := &cc_id; 
new  2: c_id customers.id%type := -6; 
ID must be greater than zero! 
 
PL/SQL procedure successfully completed. 

预定义的异常

PL/SQL 提供了许多预定义的异常，当程序违反任何数据库规则时会执行这些异常。例如，当 SELECT INTO 语句不返回任何行时，会引发预定义的异常 NO_DATA_FOUND。下表列出了一些重要的预定义异常 –